dnl
dnl davfs2 configure script
dnl

AC_PREREQ(2.50)

AC_INIT(davfs2, 0.2.3, dav-linuxfs@lists.sf.net)

AC_CONFIG_HEADER(config.h)

AC_DEFINE([_GNU_SOURCE], 1, [Define to enable GNU extensions])


AC_PROG_CC
AC_SET_MAKE
AC_PROG_INSTALL

dnl List of tests

top_builddir=`pwd`
AC_SUBST(top_builddir)

NEON_REQUIRE(0,24)
NEON_WITHOUT_ZLIB
NEON_WITHOUT_ACL
NEON_VPATH_BUNDLED(['$(top_srcdir)/libneon'], [libneon], [NEON_NORMAL_BUILD()
NEON_XML_PARSER([\$(top_builddir)/expat])
])

AC_DEFUN([DAV_CHECK_DEBUG],[
AC_ARG_WITH(debug,
        [  --with-debug        Set DEBUG],,
        [DEBUG="no"])

if test "$DEBUG" = "no"; then
	DAV_DEBUG=
else
	DAV_DEBUG="-DDEBUG -g"
fi
])


AC_DEFUN([DAV_CHECK_KERNEL],[
AC_ARG_WITH(kernel-src,
        [  --with-kernel-src        Set kernel source directory],
	[KERNEL="$withval"],
        [KERNEL="no"])

if test "$KERNEL" = "no"; then
dnl #FIXME
dnl Kernel include and /usr/include dismatch problem
dnl 
	KERNEL_SRC=/usr/src/linux
else
	KERNEL_SRC="$KERNEL"
fi
CFLAGS="-I$KERNEL_SRC/include $CFLAGS"
])

dnl Check for ViceFid in linux/coda.h
AC_DEFUN([DAV_CHECK_CODA_VICEFID], [
	AC_CHECK_TYPE([ViceFid], [
		AC_CHECK_SIZEOF([ViceFid], [], [
#include <sys/types.h> /* for misc typedefs */
#include <sys/time.h> /* for struct timespec */
/* avoid inclusion of kernel time.h, since it conflicts with the userland time.h */
#define _LINUX_TIME_H
/* needed to be able to compile with kernel headers */
# define __user
#include <linux/coda.h>
		])
	], [
		AC_CHECK_TYPE([struct CodaFid], [
			AC_DEFINE([NEW_CODA_STRUCTURES], [1], [Define to 1 if CODA uses new structure types.])
			AC_CHECK_SIZEOF([struct CodaFid], [], [
#include <sys/types.h> /* for misc typedefs */
#include <sys/time.h> /* for struct timespec */
/* avoid inclusion of kernel time.h, since it conflicts with the userland time.h */
#define _LINUX_TIME_H
/* needed to be able to compile with kernel headers */
# define __user
#include <linux/coda.h>
		])
		], [], [
#include <sys/types.h> /* for misc typedefs */
#include <sys/time.h> /* for struct timespec */
/* avoid inclusion of kernel time.h, since it conflicts with the userland time.h */
#define _LINUX_TIME_H
/* needed to be able to compile with kernel headers */
# define __user
#include <linux/coda.h>
	])
	], [
#include <sys/types.h> /* for misc typedefs */
#include <sys/time.h> /* for struct timespec */
/* avoid inclusion of kernel time.h, since it conflicts with the userland time.h */
#define _LINUX_TIME_H
/* needed to be able to compile with kernel headers */
# define __user
#include <linux/coda.h>
	])
	AC_CHECK_SIZEOF([u_int32_t], [], [
#include <sys/types.h>
	])
	AC_CHECK_SIZEOF([void *], [], [])
])

dnl Check for getopt_long
AC_CHECK_FUNC(getopt_long,,[AC_LIBOBJ(lib/getopt) AC_LIBOBJ(lib/getopt1)])

NEON_REPLACE_SNPRINTF
NEON_TEST
NEON_DEBUG
NEON_WARNINGS
DAV_CHECK_DEBUG
DAV_CHECK_KERNEL
DAV_CHECK_CODA_VICEFID
AC_SUBST(DAV_DEBUG)
AC_SUBST(KERNEL_SRC)

CPPFLAGS="$CPPFLAGS -I${top_builddir} -I\$(top_srcdir)/lib"

AC_OUTPUT([Makefile libneon/Makefile])

cat<<EOF

Using configuration for building DAVFS2 AC_PACKAGE_VERSION:

  Install prefix:  ${prefix}
  Compiler:        ${CC}
  neon library:    ${neon_library_message}
  XML parser:      ${neon_xml_parser_message}
  SSL library:     ${neon_ssl_message}
 
Now run 'make' to compile DAVFS2

EOF